Collada interactivity

package {
	import flash.display.Sprite;
	import flash.events.Event;
 
	import org.papervision3d.cameras.Camera3D;
	import org.papervision3d.view.Viewport3D;
	import org.papervision3d.scenes.Scene3D;
	import org.papervision3d.render.BasicRenderEngine;
	import org.papervision3d.events.*;
 
	import org.papervision3d.objects.primitives.*;
	import org.papervision3d.objects.DisplayObject3D;
	import org.papervision3d.objects.parsers.Collada;
 
	import org.papervision3d.materials.utils.MaterialsList;
	import org.papervision3d.materials.*;
 
	public class erl_webscape3D extends Sprite {
		private var viewport:Viewport3D;
		private var scene:Scene3D;
		private var camera:Camera3D;
		private var renderer:BasicRenderEngine;
 
		private var groundPlane:Plane;
		private var dome:Collada;
		private var pgPlane:Plane;
 
		private var gmat:MovieAssetMaterial;
		private var dome_material:MovieAssetMaterial;
		private var people_material:MovieAssetMaterial;
 
		public function erl_webscape3D() {
			initPapervision3D();
 
			createGroundPlane();
			createDome();
			createPeoplePlane(2);
 
			beginRender();
		}
 
// *********** INITIALIZATION ************		
 
		private function initPapervision3D():void {
			// create the viewport
			viewport = new Viewport3D(0, 0, true, true);
			addChild(viewport);
			viewport.buttonMode = true;
 
			// create the scene
			scene = new Scene3D();
 
			// create a camera
			camera = new Camera3D();
			camera.y = 60;
			camera.z = -1000;
			camera.zoom = 6;			
 
			// create the renderer
			renderer = new BasicRenderEngine();
		}
 
// *********** OBJECT CREATION ************		
 
		private function createGroundPlane():void {
			gmat = new MovieAssetMaterial("worldmap");
			gmat.animated = true;
			gmat.smooth = true;
			gmat.interactive = true;
 
			// width, height
			var w:Number = 1200;
			var h:Number = 600;
 
			// segments
			var sW:Number = 16;
			var sH:Number = 8;
 
			groundPlane = new Plane(gmat, w, h, sW, sH);
			scene.addChild(groundPlane);
			groundPlane.z = -840;
			groundPlane.rotationX = -90;
 
			groundPlane.addEventListener(InteractiveScene3DEvent.OBJECT_PRESS, onPress);
 
		}
 
		private function createDome():void {
			var domeMatsList:MaterialsList = new MaterialsList();
 
			//BitmapFileMaterial, doubleSided draws the color on both sides of the geometry normals
			dome_material = new MovieAssetMaterial("lightStreaks", true);
			dome_material.animated = true;			
			dome_material.doubleSided = true;
			dome_material.movie.alpha = .33;
			dome_material.interactive = true;
 
			domeMatsList.addMaterial(dome_material, "dome_material");
//			domeMatsList.addMaterial(dome_material);
 
			dome = new Collada("dome.dae", domeMatsList, .02);
			scene.addChild(dome);		
			dome.y = 2;
			dome.z = -800;
			dome.scale = .2;
 
			dome.addEventListener(InteractiveScene3DEvent.OBJECT_PRESS, onPress);
 
		}
 
		private function onPress(e:InteractiveScene3DEvent):void {
			trace ("pressing!!!!  target = " + e.target.name);
			dome.visible = false;
		}
 
		// create People Planes, then group them
		private function createPeoplePlane(groupNum:Number):void {
 
			var pg:String = "people" + groupNum;
//			var pg:String = "people1";
			people_material = new MovieAssetMaterial(pg, true);
			people_material.doubleSided = true;
			people_material.interactive = true;
			people_material.smooth = true;
 
			var w:Number = 25;
			var h:Number = 25;
 
			// segments
			var sW:Number = 4;
			var sH:Number = 4;
 
			for (var i:Number = 0; i < 2; i++) {
				pgPlane = new Plane(people_material, w, h, sW, sH);
				scene.addChild(pgPlane);
 
				pgPlane.x = Math.round(Math.random() * 10 - 5);
				pgPlane.y =  15;
				pgPlane.z = -800;
				pgPlane.rotationY = Math.round(Math.random() * 60 - 30);
			}
		}
 
// *********** RENDERING ************		
 
		private function beginRender():void {
			// calls the render function every frame
			addEventListener(Event.ENTER_FRAME, render);
		}
 
		private function render(e:Event):void {
 
			var buf:Number = 80;
			var camMargin:Number = 100;
			var diff:Number;
			var dmove:Number;
			var nmove:Number;
			var camPosX:Number;
 
			camPosX = camera.x + (((stage.mouseX-(stage.stageWidth * .5))*2)-camera.x )*.01;
 
			// if camera is close to either display limit, buffer the move so it stops moving at the limit
			diff = Math.floor(100 - Math.abs(camPosX));
			if (diff < buf) {
				dmove = camPosX - camera.x;
				nmove = dmove * (diff / 100); 
				camPosX = camera.x + nmove;
			}
 
			camera.x = camPosX;			
 
			renderer.renderScene(scene, camera, viewport);
		}
	}
}
</code